10 способов получить модуль числа (а может, и больше)

Публикация № 1091477

Разработка - Практика программирования

модуль числа интересное

39
Пишем функцию вычисления модуля числа. Сколько способов существует? Давайте посчитаем!

Всем привет, сразу

DISCLAIMER: Данная статья носит исключительно развлекательный характер, не несет в себе никакой практической пользы и написана только для того, чтобы срубить плюсов just for fun:)

Как-то раз с коллегой зашел разговор о том почему в платформе не реализована функция получения модуля числа, ведь для учетной системы это довольно нужная вещь (скорее всего разработчики платформы еще заняты написанием функции инкрементации и им не до этого, кстати если у вас есть предположения, то пишите в комментариях) и мы обсуждали, что способов написания такой функции может быть несколько и я решил посчитать, а сколько же их можно придумать. Конечно большинство из них "высосаны из пальца" и не могут использоваться на практике в виду здравого смысла, но нас это не останавливает), итак, поехали!

1.Наиболее логичный и распространенный способ, проверяем на превышение нуля и инвертируем значение при необходимости

Функция МодульЧисла1(Число)

	Возврат ?(Число >= 0, Число, -Число);
		
КонецФункции // МодульЧисла()

2.Также довольно распространенный способ, используем функцию Макс()

Функция МодульЧисла2(Число)
	
	Возврат Макс(Число, -Число);
		
КонецФункции // МодульЧисла()

На этом адекватные способы закончились) и начинаются извращения начинаем использовать

3.Перевести в строку, избавиться от минуса и конвертировать обратно в число?! Легко!

Функция МодульЧисла3(Число)
	
	ЧислоСтрокой = Формат(Число, "ЧРД=.; ЧН=; ЧГ=");
	ЧислоСтрокой = СтрЗаменить(ЧислоСтрокой, "-", "");
		
	Возврат Число(ЧислоСтрокой);
				
КонецФункции // МодульЧисла()

4.Далее вспоминаем, что можем использовать com-объекты, а это открывает нам удивительные возможности

Изначально я использовал такой код:

ЧислоСтрокой = Формат(Число, "ЧРД=.; ЧН=; ЧГ=");
Script = Новый COMОбъект("MSScriptControl.ScriptControl");
Script.Language = "javascript";
Script.Eval(СтрШаблон("var abs = Math.abs(%1);",ЧислоСтрокой));
	
Возврат Script.CodeObject.abs;	

Но в серверном контексте я получил ошибку отсутствия класса из-за различия в разрядности, а делать обертку на корпоративном сервере не хотелось, поэтому я решил использовать другой com, а именно regexp

Функция МодульЧисла4(Число)
	
	RegExp = Новый COMОбъект("VBScript.RegExp");
	RegExp.Global 		= Истина;
	RegExp.IgnoreCase 	= Истина;
	RegExp.Pattern = "\d+[.,]?\d+";
	
	Matches = RegExp.Execute(Число);
	Если Matches.Count() > 0 Тогда
		Возврат Число(Matches.Item(0).Value);
	Иначе
		ВызватьИсключение("Нет вхождения строки");
	КонецЕсли;
	
КонецФункции // МодульЧисла()

5.Используем список значений и сортируем, почему нет?

Функция МодульЧисла5(Число)
	
	СписокЗначений = Новый СписокЗначений;
	СписокЗначений.Добавить(Число);
	СписокЗначений.Добавить(-Число);
	СписокЗначений.СортироватьПоЗначению(НаправлениеСортировки.Убыв);
	
	Возврат СписокЗначений[0].Значение;
			
КонецФункции // МодульЧисла()

6.Используем запрос, в принципе это нормальный способ и т.к. вычисление производится на стороне СУБД я решил его тоже включить

Функция МодульЧисла6(Число)
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	ВЫБОР
		|		КОГДА &Число >= 0
		|			ТОГДА &Число
		|		ИНАЧЕ -&Число
		|	КОНЕЦ КАК Модуль";
	
	Запрос.УстановитьПараметр("Число", Число);
	РезультатЗапроса = Запрос.Выполнить();
	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
	ВыборкаДетальныеЗаписи.Следующий();
	
	Возврат ВыборкаДетальныеЗаписи.Модуль;
			
КонецФункции // МодульЧисла()

7.Далее вспоминаем из курса школьной программы гуглим, что

Модуль числа a – это арифметический квадратный корень из квадрата числа a, исходя из этого пишем функцию

Функция МодульЧисла7(Число)
	
	Квадрат = Pow(Число, 2);
	Корень  = Sqrt(Квадрат);
	
	Возврат Корень;
			
КонецФункции // МодульЧисла()

8.Используем Формат, чтобы избавиться от минуса и используем функцию Вычислить 

Функция МодульЧисла8(Число)
	
	ЧислоСтрокой = Формат(Число, "ЧРД=.; ЧН=; ЧГ=; ЧО=0");
	Возврат Вычислить("0+"+ЧислоСтрокой);
		
КонецФункции	

Да остановись уже!

9.Здесь вообщем то уже читерство, используем ОписаниеТипов с допустимым знаком "+" и если после приведения результат = 0, то инвертируем значение

Функция МодульЧисла9(Число)
	
	ЧислоСтрокой = Формат(Число, "ЧРД=.; ЧН=; ЧГ=");
	Подстроки    				= СтрРазделить(ЧислоСтрокой, ".");
	ЧислоРазрядов 				= СтрДлина(Подстроки[0]);
	ЧислоРазрядовДробнойЧасти 	= 0;
	Если Подстроки.Количество() > 1 Тогда
		ЧислоРазрядовДробнойЧасти = СтрДлина(Подстроки[1]);
	КонецЕсли;	
	КвалификаторЧисла = Новый КвалификаторыЧисла(ЧислоРазрядов, ЧислоРазрядовДробнойЧасти, ДопустимыйЗнак.Неотрицательный);
	ТипЧисло = Новый ОписаниеТипов("Число", КвалификаторЧисла);
	Если ТипЧисло.ПривестиЗначение(Число) = 0 Тогда
		Возврат -Число;
	Иначе	
		Возврат Число;
	КонецЕсли;	
				
КонецФункции // МодульЧисла()

Все? Нет

10.И напоследок используем такой же подход, перехватываем исключение в функции, где параметр положительное число, например, СлучайноеЧисло

Функция МодульЧисла10(Число)
	
	ГСЧ = Новый ГенераторСлучайныхЧисел;
	Попытка
		СлучайноеЧисло = ГСЧ.СлучайноеЧисло(0, Число);
		Возврат Число;
	Исключение
		Возврат -Число;
	КонецПопытки;
	
КонецФункции	

И в заключение этой "шедевральной" статьи график (обработка во вложении) по скорости выполнения на 10000 итерациях. Версия платформы: 8.3.13.1513

Ожидаемо запрос и com самый медленный ввиду инициализации объектов, а математика самая быстрая.

Знаешь еще способы - пиши в комментах!

На этом дорогие друзья у меня все, и кстати это моя первая статья (я долго копил свой опыт, чтобы поделиться им с сообществом), надеюсь, ее шуточный характер не встанет мне боком)

 

39

Скачать файлы

Наименование Файл Версия Размер
10 способов получить модуль числа (а может и больше):
.epf 8,03Kb
11.07.19
1
.epf 8,03Kb 1 Скачать

См. также

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. DJDUH 17 11.07.19 13:11 Сейчас в теме
1.Наиболее логичный и распространенный способ, проверяем на превышение нуля и инвертируем значение при необходимости

Функция МодульЧисла1(Число)

Возврат ?(Число >= 0, Число, -Число);

КонецФункции // МодульЧисла()


С точки зрения математики
>=0
.
3. ahahaev 11.07.19 14:09 Сейчас в теме
(1) Либо ?(Число < 0, -Число, Число).

Чтобы произносить было короче :D
4. sam441 38 11.07.19 14:14 Сейчас в теме
2. json 2414 11.07.19 13:43 Сейчас в теме
чисто как еще один способ

МодульЧисла = Число(СтрЗаменить(СтрЗаменить(Число, "-", ""), Символ(160), ""));
6. SlavaKron 11.07.19 14:43 Сейчас в теме
(2) Так быстрее:
МодульЧисла = Число(СтрЗаменить(XMLСтрока(Число), "-", ""));
5. singlych 11.07.19 14:37 Сейчас в теме
Возврат ?(СтрДлина(Число) > СтрДлина(-Число), -Число, Число)
Sergynia; d.menyailov@ngslab.ru; Krio2; CyberCerber; sam441; ahahaev; +6 Ответить
7. singlych 11.07.19 15:17 Сейчас в теме
А еще прикольно с БСП, правда только для целых от -99 до 999
СтроковыеФункцииКлиентСервер.ПреобразоватьЧислоВАрабскуюНотацию(СтроковыеФункцииКлиентСервер.ПреобразоватьЧислоВРимскуюНотацию(Число))
8. SlavaKron 11.07.19 15:28 Сейчас в теме
запрос и com самый медленный ввиду инициализации объектов

Вы каждую итерацию их инициализировали? Так не пойдёт, такие вещи кэшировать надо.
Мои результаты на 1 млн. итераций (в мс):
Число > 0 391
Макс 393
СтрЗаменить 4356
Число(СтрЗаменить(XMLСтрока 2179
СтрДлина 3873
Лев 1200
Sqrt 1115
user774630; +1 Ответить
9. sam441 38 11.07.19 15:48 Сейчас в теме
(8) Была такая мысль, но мы же пишем независимую функцию, работающую без дополнительных настроек, естественно, я знаю про кэш, да и в контексте "несерьезности" задачи вряд ли это имеет смысл :)
d.menyailov@ngslab.ru; user774630; +2 Ответить
10. ildarovich 6671 11.07.19 22:01 Сейчас в теме
Вот два варианта на основе "индикаторной" функции:
Функция МодульЧисла21(Число)
	
	Возврат ((Число > 0) * 2 - 1) * Число
	
КонецФункции

Функция МодульЧисла22(Число)
	
	Возврат (Число > 0) * Число - (Число < 0) * Число
	
КонецФункции
Показать
И для разнообразия
Функция МодульЧисла23(Число)
	
	Возврат - Мин(Число, - Число)
	
КонецФункции
d.menyailov@ngslab.ru; dabu-dabu; Ibrogim; spacecraft; testnv0; mvxyz; singlych; CyberCerber; Krio2; plevakin; user811769; ice-net; alalsl; Serj1C; ahahaev; sam441; json; PowerBoy; awk; Rustig; +20 Ответить
27. spacecraft 15.07.19 14:22 Сейчас в теме
(10)
Возврат (Число > 0) * Число - (Число < 0) * Число

это можно упростить:
Возврат (Число*((Число>0)-(Число<0)))
dabu-dabu; json; ildarovich; +3 Ответить
11. Rustig 1187 11.07.19 22:07 Сейчас в теме
(0) шуточные задачки развивают логическое мышление :)
rpgshnik; sam441; pm74; +3 Ответить
12. acanta 64 11.07.19 23:28 Сейчас в теме
Все, о чем молчат гусары...
13. user856012 7 12.07.19 00:55 Сейчас в теме
Неее, это другое: "Баловство это, барин, жениться вам надо..." (с)
14. kredko 19 12.07.19 06:44 Сейчас в теме
Якубович и Спанчбоб - самые главные персонажи в этой статье.
15. madonov 154 12.07.19 07:52 Сейчас в теме
18. sam441 38 12.07.19 09:44 Сейчас в теме
(15) Ну как бы в самом начале написал just for fun)
16. pm74 130 12.07.19 08:29 Сейчас в теме
шутки ради
Функция МодульЧисла_00000001(Число)  // для |Число| > 0.00000001
     Возврат -100000000*(Число-(Число+0.00000001)%(Число-0.00000001)-(Число-0.00000001)%(Число+0.00000001))*Число;
КонецФункции
17. user811769 6 12.07.19 09:12 Сейчас в теме
спасибо, повеселили с утра пораньше =)
19. rpgshnik 1610 12.07.19 10:26 Сейчас в теме
Запросы рулят, говорили они :)
20. scientes 233 12.07.19 11:08 Сейчас в теме
23. collider 12.07.19 14:03 Сейчас в теме
Функция МодульЧисла(Число)
    ДобавляемыеРеквизиты	= Новый Массив;
    НеотрицательноеЧисло = Новый РеквизитФормы("НеотрицательноеЧисло",	Новый ОписаниеТипов("Число", , , Новый КвалификаторыЧисла(10, 3, ДопустимыйЗнак.Неотрицательный)));
    ДобавляемыеРеквизиты.Добавить(НеотрицательноеЧисло);
    ИзменитьРеквизиты(ДобавляемыеРеквизиты);
	ЭтаФорма.НеотрицательноеЧисло = Число;   
	Возврат ?(ЭтаФорма.НеотрицательноеЧисло = 0, -Число, Число); 	
КонецФункции
24. morin 13 14.07.19 01:41 Сейчас в теме
Для особо искушенных: (x ^ (x >> 31)) - (x >> 31)
sam441; Yashazz; +2 Ответить
25. FesenkoA 39 15.07.19 12:05 Сейчас в теме
Можно еще создать макет, в котором заполнить все положительные числа, потом в процессе загрузить колонку в массив и проверить на наличие числа в массиве, если нету - умножить на (-1).
26. sam441 38 15.07.19 12:48 Сейчас в теме
(25)
Можно еще создать макет, в котором заполнить все положительные числа
идеально:) какое последнее число?)
28. FesenkoA 39 15.07.19 15:56 Сейчас в теме
(26) 99999999999999999999999999999999,99999999999999999999999999999999

[32,32]
29. FesenkoA 39 15.07.19 17:19 Сейчас в теме
Опять же, можно воспользоваться АПИ (типа http://mobmath.appspot.com), передать туда уравнение и получить ответ
30. FesenkoA 39 15.07.19 17:23 Сейчас в теме
Модуль=?(Pow(10, число)>1,1,-1)*число;
31. qwinter 601 16.07.19 12:36 Сейчас в теме
Какие то жуткие цифры на диаграмме)) Вы не в отладке тест сделали случайно?)) Я советую провести тест без нее и выложить результаты, т.к. первый метод должен выигрывать у второго, пусть и немного.
Оставьте свое сообщение